Constant Story "";
Constant Headline
	"^A speedIF O entry^Program by David Welbourn (dswxyz@@64look.ca)^";
Release "1";
Serial "010618";

Constant MAX_SCORE = 0;
Constant DIALECT_US = 1;

Include "Parser";
Include "VerbLib";

Object	confloor "Convention Floor"
  with	description "You are at the astrology convention in Alaska.",
  has	light;

Object  chest "large chest" confloor
  with  name "large" "chest" "trunk",
	description "This is a large chest, or trunk, which is being used
	to support a light luncheon for the convention guests.",
	react_after [;
	Open: print "Ah! The horror! Your heart skips a beat in fear! ";
	      rfalse;
	],
  has	openable container static;

Object  luncheon "luncheon" confloor
  with	name "lunch" "luncheon" "food",
	description "The luncheon on the chest is somewhat eclectic,
	featuring, amongst other things, an okra and seaweed salad,
	elderberry wine, a box of Cracker Jack(tm),
	and a selection of chocolate Kinder Eggs(tm).",
	before [;
	Eat: "Please refer to which luncheon items you wish to eat.";
	],
  has	static;

Object	okra "okra and seaweed salad" confloor
  with	name "okra" "and" "seaweed" "salad",
 	description "It looks green and leafy. It looks like it's been
	dusted with powdered sugar.",
	after [;
	Take: give self ~concealed;
	],
  has	concealed edible;

Object	wine "glass of elderberry wine" confloor
  with	name "elderberry" "wine" "glass" "of" "red",
	description "It's a glass of red wine. You can tell it's elderberry
	wine by its distinctive fruity-and-arsenic smell.",
	before [;
	Drink: deadflag = 1;
		"You drink the elderberry wine containing the arsenic
		and promptly keel over as your heart fails...";
	],
	after [;
	Take: give self ~concealed;
	],
  has	concealed;

Object	popcorn "box of Cracker Jack(tm)" confloor
  with	name "box" "of" "cracker" "jack" "peanuts" "popcorn" "carmel"
	"peanut" "candy",
	description "It's a box of Cracker Jack(tm), basically carmel
	popcorn and peanuts. There's usually a wimpy prize inside too.",
	after [;
	Take: give self ~concealed;
	],
  has	openable concealed container edible;

Object	elastic "elastic band" popcorn
  with	name "elastic" "band" "prize",
	description "It's an elastic band. Like, some prize, eh?";

Object	egg "Kinder Egg(tm)" confloor
  with	name "kinder" "egg" "eggs" "chocolate" "candy",
	description "It's a chocolate Kinder Egg(tm). Kinder Eggs have
	neat prizes inside, much much better than Cracker Jack(tm).",
	before [;
	Close: "Sorry. You can't mend a broken egg.";
	],
	after [;
	Take: give self ~concealed;
	],
  has	openable concealed container edible;

Object	gyroscope "gyroscope" egg
  with	name "gyro" "gyroscope" "toy" "prize",
	description "This is the coolest Kinder Egg(tm) prize ever!
	A gyroscope!";

Object	alex "the dead body of Alexander The Great" chest
  with	name "alexander" "the" "great" "alex" "general" "man" "corpse" "body" "cavader"
	"frozen" "stiff",
	description "This is the frozen body of Alexander the Great. Dead, of
	course -- he died in 323 B.C. -- but still looking great! For a corpse,
	that is.",
  has	proper male static;

Object	neil "Neil Gaiman" confloor
  with	name "neil" "gaiman" "man" "artist" "author",
	description "Neil Gaiman is your favourite comic book author, ever.",
	life [;
	Give: if (noun == comics && neil hasnt general)
		"~I'm hungry!~, Mr. Gaiman pouts.";
	      else if (noun == comics) {
		deadflag = 2;
		"Mr. Gaiman magnanimously signs your Sandman collection!
		At last! At last! All your fellow geeks will be so jealous...";	}
	      else if (noun == okra)
		"~I can't eat that!~, Mr. Gaiman exclaims.
		~It's covered with Nutri-Sweet! If I eat that, I get migranes.~";
	      else if (noun == popcorn)
		"~Oh thanks, but no thanks. Peanut allergy, don'tcha know.~";
	      else if (noun == wine)
		"~Are you trying to kill me? That's laced with arsenic!~";
	      else if (noun == egg && egg has open)
		"~That egg's already been opened.~";
	      else if (noun == egg) {
		remove egg;
		give neil general;
		"~Thanks!~ Neil Gaiman opens the Kinder Egg(tm), removes
		the prize inside and eats the chocolate. ~Yum, my favourite.
		Anything I can do for you?~"; }
	],
  has	proper male animate;

Object	comics "your Sandman comic book collection"
  with	name "comics" "comic" "book" "books" "collection" "your" "sandman"
	"dc" "vertigo" "graphic" "novels" "novel",
	description "Actually, FYI, these are *not* mere comic books.
	They are ~graphic novels~. They're in near-mint condition and
	in distressing need of Neil Gaiman's autograph.",
  has proper;

!-------------------------------------------------------------
[   Initialise ;
    location = confloor;
    move comics to Player;
    score = 0;
    "^^^^^^Well, here you are, in sunny sunny Alaska!! (That's sarcasm, by the way.)
     You're here to get your favorite comic book author, Neil Gaiman,
     to sign your entire collection of Sandman comic books. For some reason,
     he's here for an astrology convention. And of course, *that's* in Alaska,
     because that's where the Faboo Telescope is, in middle of nowheresville.
     Ah, the rough life of a comic book fan...";
];

Include "Grammar";